Loading...

Introduction

This tutorial gives some ideas on how to explore and use the OTRA dataset. It presupposes setting up a local triple store. Currently, a good solution is using GraphDB. For the setup, see the tutorial here.

Data Structure

As explained in Data, the main entities of the data set are Connective Claims, (Text) Blocks, and Statements. Here is an example of a Block with its Connective Claims and Statements, serialized as Turtle: 

 

@prefix otradata: <https://otraorg.github.io/data/> .
@prefix doco: <http://purl.org/spar/doco/> .
@prefix crm: <http://www.cidoc-crm.org/cidoc-crm/> .
@prefix ConnectiveOntology: <https://otraorg.github.io/ontology#> .

otradata:Epitome_bellorum__B.1.10 a doco:Paragraph ;
    crm:P67_refers_to otradata:Epitome_bellorum__S.1.10.0 ;
    crm:R15i_is_fragment_of otradata:Epitome_bellorum_sacrorum ;
    ConnectiveOntology:has_explicit "in bello et poterit nutrire." ;
    ConnectiveOntology:has_incipit "(11) Concedit pluralitatem uxorum et" .

A connective claim is usually defined by its RefSubject and RefObject

Exploration

To explore the dataset, here are some questions that we could ask

Connective Claims

What Connective Claims are made about a specific source work?

The following query will find Connective Claims that regard Jacobus de Voragine's Legenda Aurea: 
 
PREFIX hdn: <https://hdn.dantenetwork.it/ontology#>
PREFIX otradata: <https://otraorg.github.io/data/>
PREFIX lrmoo: <http://iflastandards.info/ns/lrm/lrmoo/>

SELECT ?claim ?passage WHERE {
    ?claim hdn:hasRefObject ?passage .
    ?passage lrmoo:R15i_is_fragment_of otradata:Jacobus_de_Voragine__Legenda_Aurea .
} 
ORDER BY asc(?claim)
LIMIT 10

The predicate "hdn:hasRefObject" has ConnectiveOntology:ConnectiveClaim as a range, we do not need to specify that ?claim is a ConnectiveClaim.

What Connective Claims are contained within a specific Block?

The RefSubject of a claim is usually a text passage. This text passage has a position. The position has a positionUnit, which is then the block. We therefore need to chain together these requests

 
PREFIX hdn: <https://hdn.dantenetwork.it/ontology#>
PREFIX otradata: <https://otraorg.github.io/data/>

SELECT ?claim ?fromposition WHERE {
    ?claim hdn:hasRefSubject ?passage .
    ?passage hdn:fromPosition ?fromposition .
    ?fromposition hdn:positionUnit otradata:Epitome_bellorum__B.0.4
} ORDER BY asc(?claim)

What claims point to a specific Block?

We are selecting a paragraph from Riccoldo's work, in this case paragraph 4 of chapter 3. Which claims in the data we ingested point to it?

 
PREFIX hdn: <https://hdn.dantenetwork.it/ontology#>
PREFIX otradata: <https://otraorg.github.io/data/>

SELECT ?claim WHERE {
    ?claim hdn:hasRefObject ?object .
    ?object hdn:toPosition ?start_position .
    ?start_position hdn:positionUnit otradata:Ricc_CLS__B.3.4
} limit 100

Here the results become interesting! Both a passage in the Epitome bellorum sacrorum and one in Ragusa's Comparatio Legum point at this passage.

Statements

Which statements are attached to a specific Block? 

 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX hdn: <https://hdn.dantenetwork.it/ontology#>
PREFIX otradata: <https://otraorg.github.io/data/>
PREFIX lrmoo: <http://iflastandards.info/ns/lrm/lrmoo/>

SELECT ?statement ?passage ?content WHERE {
    ?statement lrmoo:R3_realised_in ?passage .
    ?statement rdfs:label ?content .
    ?passage hdn:fromPosition ?fromposition .
    ?fromposition hdn:positionUnit otradata:Epitome_bellorum__B.0.4
} ORDER BY asc(?claim)

What statements can be found in a specific source work? 

 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX hdn: <https://hdn.dantenetwork.it/ontology#>
PREFIX otradata: <https://otraorg.github.io/data/> .
PREFIX lrmoo: <http://iflastandards.info/ns/lrm/lrmoo/>
PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

SELECT ?statement ?passage ?content WHERE {
    ?statement lrmoo:R3_realised_in ?passage .
    ?passage hdn:fromPosition ?frompos .
    ?frompos hdn:positionUnit ?positionUnit .
    ?statement rdfs:label ?content .
    ?positionUnit crm:R15i_is_fragment_of otradata:Epitome_bellorum_sacrorum
} ORDER BY asc(?claim)

Synergies and overlaps

How do we find the shared reference points between works?

All Shared Object Blocks between Ragusa's works and the Epitome bellorum sacrorum

 
PREFIX ConnectiveOntology: <https://otraorg.github.io/ontology#>
PREFIX hdn: <https://hdn.dantenetwork.it/ontology#>
PREFIX lrmoo: <http://iflastandards.info/ns/lrm/lrmoo/>
PREFIX otradata: <https://otraorg.github.io/data/>

SELECT ?positionUnit ?incipit
WHERE {
  {
    # Retrieve positionUnits for the first subject (Epitome_bellorum_sacrorum)
    ?claim1 a ConnectiveOntology:ConnectiveClaim ;
            hdn:hasRefSubject ?subject1 ;
            hdn:hasRefObject ?object1 .
    ?subject1 lrmoo:R15i_is_fragment_of otradata:Juan_de_Segovia_De_gladio_divini_spiritus .
    ?object1 hdn:fromPosition ?position1 .
    ?position1 hdn:positionUnit ?positionUnit .
    
    # Add incipit for this positionUnit
    OPTIONAL { ?positionUnit ConnectiveOntology:has_incipit ?incipit . }
  }
  UNION
  {
    # Retrieve positionUnits for the second subject (Works_of_John_of_Ragusa_on_Islam)
    ?claim2 a ConnectiveOntology:ConnectiveClaim ;
            hdn:hasRefSubject ?subject2 ;
            hdn:hasRefObject ?object2 .
    ?subject2 lrmoo:R15i_is_fragment_of otradata:Works_of_John_of_Ragusa_on_Islam .
    ?object2 hdn:fromPosition ?position2 .
    ?position2 hdn:positionUnit ?positionUnit .
    
    # Add incipit for this positionUnit
    OPTIONAL { ?positionUnit ConnectiveOntology:has_incipit ?incipit . }
  }
}
GROUP BY ?positionUnit ?incipit
HAVING (COUNT(DISTINCT ?claim1) > 0 && COUNT(DISTINCT ?claim2) > 0)

How can we find Chains of Transmission?

How is the previous work Liber denudationis represented in the Epitome bellorum sacrorum?

 
PREFIX hdn: <https://hdn.dantenetwork.it/ontology#>
PREFIX lrmoo: <http://iflastandards.info/ns/lrm/lrmoo/>
PREFIX otradata: <https://otraorg.github.io/data/>

SELECT DISTINCT ?passage ?cls_para ?ref_passage ?startpos ?startoffset ?endpos ?endoffset
WHERE {
    # Step 1: Identify passages in "Epitome_bellorum_sacrorum"
    ?passage lrmoo:R15i_is_fragment_of otradata:Epitome_bellorum_sacrorum .
    
    # Step 2: These passages are subjects of claims with specific objects
    ?claim1 hdn:hasRefSubject ?passage .
    ?claim1 hdn:hasRefObject ?object1 .
    
    # Objects have positions with specific position units
    ?object1 hdn:fromPosition ?position1 .
    ?position1 hdn:positionUnit ?cls_para .
    
    # ?cls_para should be associated with "Riccoldo_da_Monte_di_Croce__Contra_Legem_Sarracenorum"
    ?cls_para lrmoo:R15i_is_fragment_of otradata:Riccoldo_da_Monte_di_Croce__Contra_Legem_Sarracenorum .
    
    # Step 3: Establish influence relationship through "Contrarietas_Alpholica"
    ?claim2 hdn:hasRefSubject ?subject2 .
    ?claim2 hdn:hasRefObject ?ref_passage .
    ?ref_passage lrmoo:R15i_is_fragment_of  .
    
    # ?subject2 should share the same position unit with the identified claim objects
    ?subject2 hdn:fromPosition ?position2 .
    ?position2 hdn:positionUnit ?cls_para .
    
    # Ensure ?subject2 is also a fragment of "Riccoldo_da_Monte_di_Croce__Contra_Legem_Sarracenorum"
    ?subject2 lrmoo:R15i_is_fragment_of otradata:Riccoldo_da_Monte_di_Croce__Contra_Legem_Sarracenorum .
    
	# Retrieve additional information regarding the passage in *Liber denudationis*
    ?ref_passage hdn:fromPosition ?start_denu .
    ?ref_passage hdn:toPosition ?end_denu .
    ?start_denu hdn:positionUnit ?startpos .
    ?start_denu hdn:positionOffset ?startoffset .
    ?end_denu hdn:positionUnit ?endpos .
    ?end_denu hdn:positionOffset ?endoffset .
}
ORDER BY ?passage
Content:
Introduction Data Structure Exploration Connective Claims Statements Synergies and overlaps
Top